OVERVIEW

Database Systems Corp. (DSC) now provides an ODBC driver for its file management system FASTPlus. This driver is available for most WINDOWS operating systems. Utilizing this ODBC driver, users may access FASTPlus data using hundreds of programs and utilities developed under Microsoft WINDOWS. Some of the more popular products include MSQuery, Access, Lotus, and Visual Basic.

Through this driver, FASTPlus has now been "opened" to access beyond DSC products or traditional programming languages. Since FASTPlus has been fully enabled for network access, data can be updated and retrieved from local WINDOWS systems, from remote WINDOWS PCs, or from UNIX servers. The ODBC driver for FASTPlus provides WINDOWS PC users access to DSC files using industry standard SQL commands. The minimum SQL92 standards are met by this driver, plus certain extensions which are documented herein.

INSTALLATION

The FASTPlus ODBC driver is easily installed on any WINDOWS PC that has an ODBC Manager licensed and installed from Microsoft. Running a simple SETUP program installs the ODBC library (dll) and a default FASTPlus database directory (DBASE) under WINDOWS and catalogues the driver within the ODBC tables. Likewise, the library and driver may be easily un-installed.

ODBC FUNCTIONS SUPPORTED

The FASTPlus ODBC driver fully supports Level 1 compliance with the ODBC standard plus certain Level 2 features. The following is a list of the ODBC function calls that are provided with the FASTPlus library. For a complete description of each of these calls, refer to the Microsoft ODBC Programmer’s Reference Guide.

SQLAllocConnect	SQLExtendedFetch	SQLForeignKeys
SQLAllocEnv	SQLExecuteDirect	SQLFetch
SQLAllocStmt	SQLFreeConnect	SQLParamOptions
SQLBindCol	SQLFreeEnv	SQLPrepare
SQLBindParameter	SQLFreeStmt	SQLPrimaryKeys
SQLBrowseConnect	SQLGetConnectOption	SQLProcedureColumns
SQLCancel	SQLGetCursorName	SQLProcedures
SQLColAttributes	SQLGetData	SQLPutData
SQLColumnPrivileges	SQLGetFunctions	SQLRowCount
SQLColumns	SQLGetInfo	SQLSetConnectOption
SQLConnect	SQLGetTypeInfo	SQLSetCursorName
SQLDescribeCol	SQLGetStmtOption	SQLSetPos
SQLDescribeParam	SQLMoreResults	SQLSetScrollOptions
SQLDisconnect	SQLNativeSql	SQLSetStmtOption
SQLDriverConnect	SQLNumParams	SQLSpecialColumns
SQLError	SQLNumResultsCols	SQLStatistics
SQLExecute	SQLParamData	SQLTablePrivileges

SQL DICTIONARY

The FASTPlus ODBC driver shares the same dictionary as TRANSACT which is located in the DBASE directory. Thus, any existing TRANSACT based system located on a WINDOWS system can be automatically defined to ODBC as a database by simply defining a Datasource which points to the TRANSACT DBASE. The ODBC driver searches the file definition table for any FASTPlus file definitions and automatically catalogues them for use by ODBC based applications or utilities.

Any new FASTPlus file that is created using an ODBC application (CREATE TABLE command) must be defined within a Datasource. The file is created and catalogued directly into the DBASE directory pointed to by the ODBC Datasource and stored in the TRANSACT dictionary. The location of the FASTPlus file may be altered by simply copying the file to another directory and changing the file definition using TRANSACT. The FASTPlus file appears in the TRANSACT dictionary with the name defined as the uppercase of the table name used in the CREATE TABLE command. Field names are likewise uppercased.

FASTPlus files that are maintained on a network must still be defined within this local system DBASE. The file definition must be local, but the access path maintained in the dictionary may point to any networked system.

SQL SYNTAX SUPPORTED

The FASTPlus ODBC driver supports the minimum SQL92 standard syntax plus certain extensions. The following is the SQL grammar supported:

statement ::= CREATE create | DROP drop | SELECT select |  INSERT insert |  DELETE delete | UPDATE update

create ::= TABLE tablename (createcols) | INDEX createindex  | UNIQUE INDEX createindex

createindex ::= ON table (columnlist)

tablename ::= identifier

createcols ::= createcol, createcols | createcol

createcol ::= columnname datatype | columnname datatype  (integer) | columnname datatype (integer, integer)

datatype ::= identifier

columnname ::= identifier

drop ::= TABLE table | INDEX table.columnname

select ::= selectcols FROM tablelist where groupby having  orderby

delete ::= FROM table where

insert ::= INTO table insertvals

update ::= table SET setlist where

setlist ::= set | setlist, set

set ::= column = NULL | column = expression

insertvals ::= (columnlist) VALUES (valuelist) | VALUES (valuelist)

columnlist ::= column, columnlist | column

column ::= columnname

valuelist ::= NULL, valuelist | expression, valuelist | expression  | NULL

selectcols ::= selectallcols * | selectallcols selectlist

selectallcols ::= | ALL | DISTINCT

selectlist ::= expression, selectlist | expression | ROWID,        selectlist

where ::= | WHERE boolean

having ::= | HAVING boolean

boolean ::= and | and OR boolean

and ::= not | not AND and

not ::= comparison | NOT comparison

comparison ::= (boolean) | colref IS NULL | colref IS NOT NULL | expression LIKE pattern | expression NOT LIKE pattern | expression IN (valuelist) | expression NOT IN (valuelist) |

                        expression op expression

op ::= > | >= | < | <= | = | <>

pattern ::= string | ? | USER

expression ::= expression + times | expression - times | times

times ::= times * new | times / neg | neg

neg ::= term | + term | - term

term ::= (expression) | colref | simpleterm | aggterm

aggterm ::= COUNT ( * ) | AVG (expression) | MAX (expression ) |

                   MIN (expression) | SUM (expression)

simpleterm ::= string | realnumber | ? | USER | date | time | timestamp

groupby ::= | GROUP BY groupbyterms

groupbyterms ::= colref | colref, groupbyterms

orderby ::= | ORDER BY orderbyterms

orderbyterms ::= orderbyterm | orderbyterm, orderbyterms

orderbyterm ::= colref asc | integer asc

asc ::= | ASC | DESC

colref ::= aliasname.columnname | columnname

aliasname ::= identifier

tablelist ::= tableref, tablelist | tableref

tableref ::= table | table aliasname

table ::= tablename

identifier ::= an identifier (identifiers containing spaces must be enclosed in double quotes)

string ::= a string (enclosed in single quotes)

realnumber ::= a non-negative real number

integer ::= a non-negative integer

date ::= a date in ODBC escape clause format (for example, {d’1997-02-12’} or --(* vendor(Microsoft),product(ODBC) d’1997-02-12’ *)--

time ::= a time in ODBC escape clause format (for example, {t ’10:20:48’} or --(* vendor(Microsoft),product(ODBC) t ’10:20:48’ *)--

timestamp ::= a timestamp in ODBC escape clause format (for example,

• {ts ‘1997=02-12 10:20:48.520’} or

• --(* vendor(Microsoft),product(ODBC) d’1997-02-12 10:20:48.520’ *)--